【 FPGA 】按键消抖与LED灯流动小实验

记录一个小实验吧，实验的目的是仅仅是塞塞牙缝而已，没其他意思，很简单。

功能：拨码开关控制led灯工作与否，拨码开关为on，led灯工作，否则不工作；导航按键up和down，也就是独立按键而已，控制led等流动方向。当按下导航开关up时，led灯从高到低流动，按下down时，led灯从低到高流动。

分析：拨码开关没啥说的，很简单，拨码开关为on，也就是为低电平时，用一个使能寄存器变量led_en控制led灯处于工作状态。

至于导航按键，存在一个抖动问题，所以需要进行去抖动操作，去抖动操作的方法有很多，这里依然沿用最简单的方式，见曾经的博文分析：《按键消抖与LED控制》实验的个人思考与总结

这里使用的代码是特权的，但是按键抖动部分，我改成了我能看懂的，也就是最简单的方式。

led灯的流动使用移位的方式实现。代码如下：

使用硬件平台实现的时候，记得进行物理约束，也即管脚约束即可。

      /
      //工程硬件平台： Xilinx Spartan 6 FPGA
      /
      //拨码开关SW3作为开关信号，导航按键UP和DOWN作为LED流动方向控制信号，实现8个LED开关、方向可控的流水灯功能
      module sp6_ljs(
      			input ext_clk_25m,	//外部输入25MHz时钟信号
      			input ext_rst_n,	//外部输入复位信号，低电平有效
      			input switch,	//拨码开关SW3输入，ON -- 低电平；OFF -- 高电平
      			input key_upup,key_down,	//up和down两个导航按键输入，未按下为高电平，按下后为低电平
      			output reg[7:0] led		//8个LED指示灯接口 
      		);
      //-------------------------------------
      //按键抖动判断逻辑
      reg key;	//所有按键值相与的结果，用于按键触发判断
      reg key_r;  //按键值key的缓存寄存器
      wire key_an;
      always @(posedge ext_clk_25m or negedge ext_rst_n)
      if (!ext_rst_n) key <= 1'b1;
      else key <= key_upup & key_down;
      always @(posedge ext_clk_25m or negedge ext_rst_n)
      if (!ext_rst_n) key_r <= 1'b1;
      else key_r <= key;
      assign key_an = key_r&(~key); //只有按键状态变化，key_an都会出现一个高电平，是由于按键抖动引起的
      //如下示意：
      // key 1 1 1 1 0 1
      //~key 0 0 0 0 1 0
      //key_r 1 1 1 1 0 1
      //key_an 0 0 0 1 0
      //-------------------------------------
      //定时计数逻辑，用于对按键的消抖判断
      reg[19:0]  cnt;
      always @ (posedge ext_clk_25m or negedge ext_rst_n)
        if (!ext_rst_n) cnt <= 20'd0;
     	else if(key_an) cnt <=20'd0;
     	else if(cnt < 20'd999_999) cnt <= cnt + 1'b1;
     	else cnt <= 20'd0;
      reg[1:0] key_value[1:0];
      always @(posedge ext_clk_25m or negedge ext_rst_n)
      if (!ext_rst_n) begin
      		key_value[0] <= 2'b11;
      		key_value[1] <= 2'b11;
      	end
     	else if(cnt == 20'd999_999) begin	//定时键值采集
      		key_value[0] <= {key_upup,key_down};
      		key_value[1] <= key_value[0];
      	end
      wire[1:0] key_press = key_value[1] & (~key_value[0]);		//消抖后按键值变化标志位 
      //------------------------------------
      //流水灯开启、停止和流动方向控制开关、按键值采集
      reg led_en;		//LED流水灯工作使能信号，高电平有效
      reg led_dir;	//LED流水灯方向控制信号，1--从高到低流动，0--从低到高流动
      always @ (posedge ext_clk_25m or negedge ext_rst_n)
     	if(!ext_rst_n) begin
      		led_en <= 1'b0;
      		led_dir <= 1'b0;
      	end
     	else begin
     		//流水灯开启/停止控制
     		if(!switch) led_en <= 1'b1; //拨码开关为on时，led灯工作
     		else led_en <= 1'b0;
     		//流水灯方向控制
     		if(key_press[0]) led_dir <= 1'b0;	//从低到高流动
     		else if(key_press[1]) led_dir <= 1'b1;	//从高到低流动
     		else ;
      	end
      //------------------------------------
      //LED流水灯变化延时计数器
      reg[23:0] delay;
      always @ (posedge ext_clk_25m or negedge ext_rst_n)
     	if(!ext_rst_n) delay <= 24'd0;
     	else delay <= delay+1'b1;
      //-------------------------------------
      //流水灯开启、停止和流动切换控制
      always @ (posedge ext_clk_25m or negedge ext_rst_n)
     	if(!ext_rst_n) led <= 8'b1111_1110;
     	else if((delay == 24'h3fffff) && led_en) begin
     		case (led_dir)
     			1'b0: led <= {led[6:0],led[7]};	//从低到高流动 
     			1'b1: led <= {led[0],led[7:1]};	//从高到低流动
     			default: ;
      		endcase
      	end
     	else ;
      endmodule
  
 

实验证明，很完美。

文章来源: reborn.blog.csdn.net，作者：李锐博恩，版权归原作者所有，如需转载，请联系作者。

原文链接：reborn.blog.csdn.net/article/details/86500341